• Below is an input file the a basic MAS simulation of 2 CSAs...the crystal file came from the BlochLib distribution.

spins{
       
       #the global options
       numspin 2
       T 1H 0
       T 1H 1

       C 5000 2134 0 0
       C -5000 2789 0.5 1
}

parameters{        

       powder{
               aveType ../../../../crystals/rep256
       }                

#the intergrator step size        
       maxtstep=1e-6

#number of 1D fid points        
       npts1D=512        

#sweepwidth
       sw=40000
       
       roeq= Iz        
       detect=Ip        
       filesave=data        
}


pulses{

#set the spinning        
       wr=2000
#set the rotor to the magic angle
       rotor=rad2deg*acos(1/sqrt(3))
#set the detection matrix
       detect(Ip)
#set the inital matrix
       ro(Ix)

#no pulses nessesary for ro=Ix

#collect the fid
       fid()
       savefidtext(simpMAS) #save as a text file
}

Here is the generated spectrum

• Below is an input file the a basic static simulation of '2D' both projection should give exactly the same thing...a boring example, but a proof of point.

spins{
    
    #the global options
   numspin 2
   T 1H 0
   T 1H 1
    
   C 5000 2134 0 0
   C -5000 2789 0.5 1
}


parameters{    

    powder{
        aveType ../../../../crystals/rep256
    }        

#the intergrator step size    
    maxtstep=1e-6

#number of 1D fid points    
    npts1D=256    

#sweepwidth
    sw=10000

#the eq matrix
    roeq=Ix
}


pulses{

#our 2D points
    fidpts=256
    2D()
#set the spinning    
    wr=2000
#set the rotor
    rotor=rad2deg*acos(1/sqrt(3))
    
#set the detection matrix
    detect(Ip)
#set our initial matrix
    ro(Ix)
    dwell2D=0.00002
#set the inital matrix
    loop(i=0:fidpts-1)       
    #collect the fid (to get the first point)
        fid(i)
    
    #do not need to propogate the last point
        if(i!=(fidpts-1))    
        #a delay for the second dim
            1H:delay(dwell2D)    
        end
    end
    savefidmatlab(2dmas) #save as a matlab file
}

    

Here is the generated spectra

• This example collects an MAS fid using the 'direct' method. With methods advances the propogator in a point-by-point fashion. This is much slower then the compute method usually used, but this just goes to show that you can do it if you wish.

# a simple MAS collection
# using the basic algorithms
# this one is essentially the same as perfomring a 'direct'
# computation of the fid (dyson time series)

spins{    
    #the global options
    numspin 2
    T 1H 0
    T 1H 1
    C 5000 2134 0 0
    C -5000 2789 0.5 1
}

parameters{    

    powder1{
        aveType ../../../../crystals/rep256
    }        

#the intergrator step size    
    maxtstep=1e-6

#number of 1D fid points    
    npts1D=256    
}


pulses{    
    ptop()
#set the spinning    
    wr=3000
#set the rotor
    rotor=rad2deg*acos(1/sqrt(3))
#set the detection matrix
    detect(Ip)
#set our initial matrix
    ro(Iz)
    
    dwell2D=0.00002

#give our spins a 90
    1H:pulse(1/150000/4, 0, 150000)    

    loop(i=0:npts1D-1)
    #collect the fid
        fid(i)
    
        if(i!=(npts1D-1))
            1H:delay(dwell2D)    
        end
    end

    savefidtext(ptopMAS) #save as a text file
}

    

The generated spectra will look like the first 'basic' example, however, i have noticed several 'phase-noise' that become present when performing the 'driect' dyson series for spinning simulations. There are thousands of propogators that need to be calculated and if the time dt step is choosen to be too small it will devolope both frequecy and phase errors. These errors will propogate thus creating undesired peaks and oddly phased peaks.